uniform sampler2D uTexGarbage;
uniform float uTime;

in vec4 aColour;
in vec2 aUv;
in vec3 aNorm;
in vec3 aCo;
in vec3 aWorldCo;

#include "common_world.glsl"
#include "motion_vectors_fs.glsl"

void main()
{
   compute_motion_vectors();

   vec3 rd = normalize(aNorm);

   float fintensity = 1.0-(abs(rd.y)*0.7);
   float fblend = pow(fintensity,4.0);
   vec3 horizon = vec3( 0.87, 0.93, 0.98 );
   vec3 skycolour = vec3( 0.16, 0.58, 0.95 ) - rd.y*rd.y*0.5;
   vec3 diffuse = mix( skycolour, horizon, fblend );

   float fmove = uTime * 0.004;
   vec2 cloudplane = (rd.xz / (rd.y*sign(rd.y))) * 0.05;
   vec4 clouds1 = texture( uTexGarbage, cloudplane + vec2(0.1,0.4)*fmove*2.0 );
   vec4 clouds2 = texture( uTexGarbage, cloudplane*2.0 + vec2(0.3,0.1)*fmove );

   float cloud_d = max(clouds1.b*clouds2.r -0.2 - clouds2.g*0.4,0.0);
   float cloud_e = pow(cloud_d,1.5)*pow(abs(rd.y),0.3)*2.0;

   vec3 colour_ocean = vec3( 0.61, 0.84, 0.9 );
   float fhorizon = step( rd.y * 0.5 + 0.5, 0.5 );

   vec3 skycomp = mix(diffuse, vec3(1.0,1.0,1.0), cloud_e);


   float sundot = clamp(dot(rd, -g_light_directions[0].xyz), 0.0, 1.0);
   vec3 sun = 0.25 * vec3(1.0,0.7,0.4) * pow( sundot,5.0 );
   sun += 0.25 * vec3(1.0,0.8,0.6) * pow( sundot,64.0 );
   sun += 0.2 * vec3(1.0,0.8,0.6) * pow( sundot,512.0 );
   skycomp += sun * g_light_colours[0].rgb;

   oColour = vec4(skycomp,1.0);
}